Enneper Surfaces

Parametrization

HigherOrderEnneper[n_][r_,t_]:={((r (Cos[t]+2 n Cos[t]-(r^(2 n)) Cos[t+2 n t]))/(2+4 n)),-((r (Sin[t]+2 n Sin[t]+(r^(2 n)) Sin[t+2 n t]))/(2+4 n)),(((r^(1+n)) Cos[(1+n) t])/(1+n))};

normal[n_][r_,t_]:={((2 (r^n) Cos[n t])/(1+(r^(2 n)))),((2 (r^n) Sin[n t])/(1+(r^(2 n)))),1-(2/(1+(r^(2 n))))}

Maximal Embedded Piece

tmin[n0_]:=t/.FindRoot[ (Cos[t]-Cot[t+2 n0 t] Sin[t]-2 n0 Cot[t+2 n0 t] Sin[t]),{t,Pi/(2n0+1)+.1,2Pi/(2n0+1)-.1}]

rmin[n0_]:=(Csc[t0+2 n0 t0] (-Sin[t0]-2 n0 Sin[t0]))^(1/(2n0))/.t0->tmin[n0]

Generate Surface

n0=5;

ParametricPlot3D[HigherOrderEnneper[n0][r,t],{r,0,rmin[n0]},{t,0,2Pi},PlotRange->All,Mesh->{5,2n0+1},MaxRecursion->3,Axes->False,Boxed->False]